 > restart:

Examen extraordinario de Febrero, 19/01/1996.

Cálculos para la resolución numérica del ejercicio 6, correspondiente al cable del transbordador del Niágara, de Torres Quevedo.

Los datos son:

• P = 9070 kg es el valor del contrapeso de cada uno de los 6 cables (Canadian engineer, 1916: 20 ton; 1 ton USA = 20000 lb)

• q = 3.47 kg/m es el peso propio del cable (Canadian engineer, 1916: flecha sin carga=14.51 m)

• Q = 1058 kg es el peso por cable del carro (Canadian engineer, 1916: 7 ton lleno, para 6 cables)

• L = 549 m es la luz del cable (Canadian engineer, 1916: 1800 ft entre Colts pt. y Thompsons pt.)

Con estos datos, se pide:

1. calcular la flecha de los cables sin el carro, admitiendo la hipótesis simplificadora, al estar el cable muy tenso, de que la carga es constante por unidad de abscisa horizontal (parábola).

2. calcular la flecha de los cables con el carro.

 > P:=9070;q:=3.47;L:=549;Q:=1058;

P := 9070
q := 3.47
L := 549
Q := 1058

1. Cable sin carro

T 0: tensión horizontal del cable admitiendo que es una parábola, y la tensión vertical máxima es q(L/2):

 > T0:=sqrt(P^2-(q*L/2)^2);

T0 := 9019.845629

Aplicando la fórmula de la parábola se obtiene la flecha directamente:

 > f:=(1/2)*(q/T0)*(L/2)^2;

f := 14.49389370

Resolvemos la catenaria para comparar la exactitud de la solución. Primero debemos solucionar una ecuación no lineal numéricamente para obtener el valor del parámetro a de la catenaria:

 > a0:=fsolve( q*a*cosh(L/(2*a))=P, a, 1..5000 );

a0 := 2599.325183

Maple V Release 3 2

Comprobación de la solución obtenida:

 > q*a0*cosh(L/(2*a0))=P;

9070.000003 = 9070

El valor f de la flecha calculada como catenaria es muy próximo al antes obtenido, lo que corrobora la validez de la hipótesis simplificadora admitida:

 > f0:=a0*cosh(L/(2*a0))-a0;

f0 := 14.507671

2. Cable con carro

La situación pésima es obviamente la del carro en medio del vano. Se forman dos arcos simétricos de catenaria, cuyo vértice está situado a una distancia α del centro del vano. Las incógnitas son pues el parámetro a de la catenaria y el valor de α. La primera ecuación que podemos escribir es la tensión vertical del cable en el punto de suspensión del carro, que será igual a la mitad del peso del mismo (por simetría):

 > unassign('a');eq1:=q*a*sinh(alpha/a)=Q/2;

eq1 := 3.47 a sinh (\frac{α}{a}) = 529

La segunda ecuación corresponde a la tensión del cable en el extremo, tensión máxima que debe igualar al contrapeso:

 > eq2:=q*a*cosh((alpha+L/2)/a)=P;

eq2 := 3.47 a cosh (\frac{α + \frac{549}{2}}{a} ) = 9070

Resolviendo numéricamente (es necesario dar a maple alguna indicación sobre el rango de valores en donde buscar soluciones; escogemos un ango amplio)

 > sol:=fsolve({eq1,eq2},{alpha,a},{alpha=1..1000,a=1..5000});

sol := { α = 152.3608852, a = 2578.418361 }

Comprobación del cumplimiento de la ecuaciones (Santo Tomás):

 > eval(subs(sol,{eq1,eq2}));

{ 529.0000001 = 529, 9069.999997 = 9070 }

Calculamos ahora la flecha para la solución obtenida, mediante la ecuación de la catenaria:

 > alpha:=subs(sol,alpha);a:=subs(sol,a);
 > f:=a*cosh((alpha+L/2)/a)-a*cosh(alpha/a);

α := 152.3608852
a := 2578.418361

Maple V Release 3 3

f := 30.911616

Otra forma de asignar los valores de la solución obtenida:

 > # op(sol[1])[2];op(sol[2])[2];

Otra manera de resolver este caso sería eliminar una de las dos incógnitas anteriores, para obtener una sola ecuación con una incógnita. Este método puede resultar más cómodo si la resolución iterativa se realiza a mano. Para ello, basta con desarrollar el coseno hiperbólico de la suma,

 > unassign('a','alpha');expand(cosh((alpha+L/2)/a));

cosh (\frac{α}{a}) cosh (\frac{549}{2} \frac{1}{a}) + sinh (\frac{α}{a}) sinh (\frac{549}{2} \frac{1}{a})

y eliminar así la variable α, obteniéndose una única ecuación:

 > eq:=sqrt((q*a)^2+(Q/2)^2)*cosh((L/2)/a)+(Q/2)*sinh((L/2)/a)=P;

eq := \sqrt{12.0409 a^{2} + 279841} cosh (\frac{549}{2} \frac{1}{a}) + 529 sinh (\frac{549}{2} \frac{1}{a}) = 9070

 > fsolve(eq,a,1..5000);

2578.418361

(comprobamos que el resultado para a es el mismo que antes) Dibujamos el resultado, para comparar la flecha en ambos casos:

 > alpha:=subs(sol,alpha);a:=subs(sol,a);f1:=f+a*cosh(alpha/a)-a;

α := 152.3608852
a := 2578.418361
f1 := 35.414491

 > dibujo:=plot({a*cosh((abs(x)+alpha)/a)-a-f1,a0*cosh(x/a0)-a0-f0},x=-L/2..L/2,\
 > title=`comparacion del cable con y sin carro`,thickness=2 ):
 > interface(plotdevice=win,plotoutput=terminal);plots[display](dibujo);
 > plotsetup(ps,plotoutput=`635exam.eps`,plotoptions=`portrait,noborder`);\
 > plots[display](dibujo);

Deducción del valor del peso del cable, a partir del dato de Canadian engineer de flecha sin carro (f = 14.51 m):

 > L:=549;f:=14.51;P:=9070;

L := 549
f := 14.51

Maple V Release 3 4

Figure 1: Comparación de configuraciones del cable, con y sin carro P := 9070

 > unassign('a'):eq1:=a*cosh((L/2)/a)-a=f;

eq1 := a cosh (\frac{549}{2} \frac{1}{a}) − a = 14.51

 > a:=fsolve(eq1,a,1..5000);

a := 2598.908537

comprobación:

 > eq1;

14.510000 = 14.51

El valor de q buscado es pues

 > unassign('q'):solve(q*a*cosh((L/2)/a)=P,q);

3.470550113